###

# Client

# require jQuery, underscore

###



# [...]



$ ->

  players = []

  socket  = io.connect '/?id=1'

  client  =

    id: 1

    x : 0

    y : 0

    hp: 100



  # Récupération des joueurs depuis le serveur

  socket.on 'sendPlayers', (pPlayers) ->

    players.push player for player in JSON.parse pPlayers



  client.move = (x, y) ->

    # On fait la modif coté client tout de suite

    # Sans la prédiction, on aurait attendu la réponse du server d'abord

    client.x = x

    client.y = y

    # Animation...

    # On avertit le server s'il s'agit du client

    # => dans un cas réel, la méthode move() vient d'une classe Player

    # => pour l'exemple j'ai abrégé en client.move()

    socket.emit 'move', client if this is client



  # Si le server nous avertir du déplacement d'un joueur

  socket.on 'move', (pPlayer) ->

    for player in players when player.id is pPlayer.id

      player.move pPlayer.x, pPlayer.y



  client.attack = (target) ->

    # On fait la modif coté client tout de suite

    # Sans la prédiction, on aurait attendu la réponse du server d'abord

    target.hp -= 10

    # Animation...

    # On avertit le server s'il s'agit du client

    # => dans un cas réel, la méthode attack() vient d'une classe Player

    # => pour l'exemple j'ai abrégé en client.attack()

    socket.emit 'attack', target if this is client



  # Si le server nous avertit de l'attaque d'un joueur

  socket.on 'attack', (pPlayer, pTarget) ->

    for player in players when player.id is pPlayer.id

      player.attack pTarget



  # On vérifie si l'état du jeu côté client et le même que coté server

  # Si ça n'est pas le cas, on rétablit l'état du jeu comme sur le server

  # Note : pas optimisé car peut obliger à renvoyer beaucoup trop de données à intervalle régulier

  # On pourrait stocker côté client l'état du jeu dans une pile puis restituer selon un timestamp ou un ID incrémenté au fur et à mesure des actions...

  socket.on 'checkState', (pPlayers) ->

    sameState = yes

    sameState = _.isEqual(player, players[i]) and sameState for player, i in JSON.parse pPlayers

    if sameState is no

      players = []

      players.push player for player in JSON.parse pPlayers

###

# Server

# require Socket.IO

###



# [...]

players = []

client  = null

io      = require('socket.io').listen 80



# Connexion à Socket.IO

io.sockets.on 'connection', (socket) ->



  # On définit l'état du client

  client =

    id: socket.handshake.query.id #/?query=id

    x : 0

    y : 0

    hp: 100

  players.push client

  # On envoie l'état des joueurs au client (pas optimisé si on a beaucoup de joueurs => /!\ bande passante)

  socket.emit 'sendPlayers', JSON.stringify players # (JSON.stringify Array) => JSON



  # Mise à jour coordonnées du joueur 

  socket.on 'move', (pPlayer) ->

  # Vérifications préalables : assez d'énergie, client devant la cible, pas d'obstacle ect...

    for player in players when player.id is pPlayer.id

      # Note : on peut factoriser le code et partager les méthodes de classe entre le client et le serveur

      player.x = pPlayer.x

      player.y = pPlayer.y

    # Note : broadcast envoie à tout le monde sauf le client

    socket.broadcast.emit 'move', pPlayer



  # Attaque d'un joueur

  socket.on 'attack', (target) ->

    # Vérifications préalables : assez d'énergie, client devant la cible, pas d'obstacle ect...

    for player in players when player.id is target.id

      player.hp -= 10

    # Note : broadcast envoie à tout le monde sauf le client

    socket.broadcast.emit 'attack', client, target



  # Pour l'exemple, j'utilise un timer de 1 seconde

  # Meilleure implémentation : faire la vérif à chaque fois qu'on reçoit un ping

  setInterval ->

    socket.emit 'checkState', JSON.stringify players # (JSON.stringify Array) => JSON

  , 1000

Citation :Mais quand est ce qu il y a correction ?

Genre le serveur n est pas d accord avec la position du client ?

Citation :1) La tel que je comprends, le joueur fait ce qu il veut sur son navigateur
2) On pourrait imaginer qu il déplace son perso autrement que par le code client du concepteur
(genre je me déplace deux fois plus vite que prévu)

Citation :Et la delta potentiel non ? Pourquoi broadcaster ?

Citation :2) On pourrait imaginer qu il déplace son perso autrement que par le code client du concepteur
(genre je me déplace deux fois plus vite que prévu).